Hopefully, I can figure out how to post this....

Here is a copy of the J10 program I use for the SSII board. I tweaked a few things. Thanks to ghoot for sharing the base Type 3 program for all of us to use and learn from. Much appreciated!
I am not a seasoned programmer, so if you see something that looks strange, it probably is! To my knowledge it's been working for me, this custom program speeds up the J10.

I also recommend using a 2GB sd card for the fastest boot up timing. A 4GB and above slows down the camera about 0.2 seconds.

symbol ShutterPin=0
symbol CameraPowerPin=1
symbol TrailFeederSwitchPin=pin4
symbol MotionSensorInputPin=pin3
symbol LEDpin=2
'symbol PAXE=5
symbol ActivityMode=bit0 '0=off and 1 = on
symbol StartWithWalkTestONorOff=bit1
symbol CameraIsONorOFF=bit2 'keep track of camera being on or off for activity mode
symbol TimeToTurnCamOnToRefreshFlash=w3
symbol TmeWaitAfterCamOnToPresShuter=w4
symbol DelayBetweenPictures=w5
symbol TimeForWalkTestToEnd=w6 'delay for walktest
symbol i=b1
disablebod
Low ShutterPin
Low CameraPowerPin
Low LEDpin
input 4
CameraIsONorOFF = 0
Pause 5000
'++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

TimeToTurnCamOnToRefreshFlash=50000 ' 25,000 = 1 hour, 50,000 = 2 hours with NAP3 (.144)
TmeWaitAfterCamOnToPresShuter=1200'"1.2 sec"
StartWithWalkTestONorOff = 1 'on = 1 off = 0
DelayBetweenPictures=13 '13 = 30 seconds between pics in feeder mode
TimeForWalkTestToEnd = 208 'Time for walktest 0.144 secondss for nap3(208x0.144 = 30 seconds)

'++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
Walktst:
IF StartWithWalkTestONorOff = 1 Then
w1=w1+1
NAP 3
IF MotionSensorInputPin = 1 Then
High LEDpin
Pause 1000
Low LEDpin
Pause 3000 'for sensor to settle
w1=0
EndIF
IF w1 >=TimeForWalkTestToEnd Then
StartWithWalkTestONorOff = 0
For i = 1 to 10
High LEDpin
Pause 200
Low LEDpin
Pause 100
next i
Pause 1000
GoTo lowpower
EndIF
EndIF
GoTo Walktst
lowpower:
IF MotionSensorInputPin=1 Then
IF CameraIsONorOFF=0 Then
Pause 10
IF TrailFeederSwitchPin = 1 Then
ActivityMode=0
Else
ActivityMode=1
EndIF
EndIF
IF ActivityMode = 0 Then
If CameraIsONorOFF=0 Then
Pause 10
High CameraPowerPin ' Turn Camera ON
Pause 700 ' Hold Power button down for 0.7 sec
Low CameraPowerPin
CameraIsONorOFF=1
Pause TmeWaitAfterCamOnToPresShuter
endif
High ShutterPin ' Take a Picture
Pause 3000 ' Hold Shutter button down for 3.0 sec
Low ShutterPin
Sleep 5
High CameraPowerPin ' Turn Camera OFF
Pause 500
Low CameraPowerPin
CameraIsONorOFF=0
w1=0
Sleep DelayBetweenPictures
EndIF
IF ActivityMode = 1 Then
IF CameraIsONorOFF=0 Then
Pause 10
High CameraPowerPin ' Turn Camera ON
Pause 700 'Hold Power button down for 0.7 sec
Low CameraPowerPin
CameraIsONorOFF=1
Pause TmeWaitAfterCamOnToPresShuter
EndIF
High ShutterPin ' Take a Picture
Pause 3000 'Hold Shutter button down for 3.0 sec
Low ShutterPin
Pause 2000
w1=0
EndIF
w2=0
EndIF
IF CameraIsONorOFF=1 Then
w1=w1+1
IF w1>=300 Then 'Keep Camera on for 30 seconds for Activity Mode
High CameraPowerPin ' Turn Camera ON
Pause 1000
Low CameraPowerPin
CameraIsONorOFF=0
w1=0
Sleep 2
EndIF
EndIF


w2=w2+1
IF w2 >= TimeToTurnCamOnToRefreshFlash Then
High CameraPowerPin ' Turn Camera ON
Sleep 1
Low CameraPowerPin
Sleep 5
High CameraPowerPin ' Turn Camera ON
Sleep 1
Low CameraPowerPin
w2=0
Pause 1000
EndIF
NAP 3
GoTo lowpower ' Do it forever
End

Thanks Paul

Sweet - thanks for posting this!

_________________
Whenever U Can - GET OUTSIDE!